class Cons s t a b | s -> a, t -> b, s b -> t, t a -> s where
  _Cons :: L.Prism s t (Tuple a s) (Tuple b t)

class Snoc s t a b | s -> a, t -> b, s b -> t, t a -> s where
  _Snoc :: L.Prism s t (Tuple s a) (Tuple t b)

cons :: forall s a. Cons s s a a => a -> s -> s
cons = curry (simply L.review _Cons)

uncons :: forall s a. Cons s s a a => s -> Maybe (Tuple a s)
uncons = simply L.preview _Cons

snoc :: forall s a. Snoc s s a a => s -> a -> s
snoc = curry (simply L.review _Snoc)

unsnoc :: forall s a. Snoc s s a a => s -> Maybe (Tuple s a)
unsnoc = simply L.preview _Snoc

_head :: forall s a. Cons s s a a => L.Traversal' s a
_head = _Cons <<< L._1

_tail :: forall s a. Cons s s a a => L.Traversal' s s
_tail = _Cons <<< L._2

_init :: forall s a. Snoc s s a a => L.Traversal' s s
_init = _Snoc <<< L._1

_last :: forall s a. Snoc s s a a => L.Traversal' s a
_last = _Snoc <<< L._2

type Parser s a = L.Prism' s (Tuple a s)

char :: forall s a. Cons s s a a => Parser s a
char = _Cons

runParser :: forall s a. L.Fold' (First (Tuple a s)) s (Tuple a s) -> s -> Maybe (Tuple a s)
runParser = L.preview

runPrinter :: forall s a. L.Review' s (Tuple a s) -> (Tuple a s) -> s
runPrinter = L.review